rulec の診断

rulec が出しうるコードの全部について、いつ出るかと、どう直すかを書いています。コードと JSON の形は安定 API で、変わるのは文面の改善だけです。一件だけ読むときは rulec explain E101 を使ってください。

E001

error — 文字列が閉じていません

いつ出るか。 " で開いた文字列が、その行のうちに閉じていないとき。セルの中にも description にも改行は書けません。

直し方。 その行のうちに " を閉じてください。長い説明は一行に収めるか、# のコメントに移してください。

最小の再現:

rule t(t) v1
description "unterminated

関係するコード: E002

E002

error — 読めない文字があります

いつ出るか。 名前の位置に、文字でも _ でもない文字（記号や制御文字）があるとき。括弧に入れた別名が名前になっていないとき（六十(60)）も同じです。打ち間違いが黙って名前になったり、別名が黙って消えたりするのを防ぐための検査です。

直し方。 その文字を消してください。名前は文字か _ で始まります（@x(x) なら x(x)、六十(60) なら 六十(size_60)）。

最小の再現:

rule t(t) v1

inputs
  %x(x) : bool

関係するコード: E001, E009

E003

error — ファイルが rule の行で始まっていません

いつ出るか。 一つの .rule は一つの規則で、先頭行が規則名と版です。空行とコメントより前に他の宣言があるとき、または rule の行に名前が無いとき。名前の無い rule の行は、いままで何も言われずに、中身の無い規則として検査を通っていました。

直し方。 先頭に rule 規則名(alias) v1 の一行を足してください。

最小の再現:

inputs
  x(x) : bool

関係するコード: E004, E011

E004

error — 行の先頭に語がありません

いつ出るか。 表でもコメントでも空行でもない行が、記号で始まっているとき。この構文は行指向なので、行の先頭の語が何の宣言かを決めます。

直し方。 行頭に宣言の語を書いてください（description / import / enum / group / inputs / elements / outputs / derive / define / constraint / table / fold / count / sum / max / min / sequence / result / examples / policy / overrides / clause / source / apply / shape / machine / scenario / prerequisites / chances / open）。表の行なら | で始めてください。

最小の再現:

rule t(t) v1

= 1

関係するコード: E003, E005

E005

error — この位置に書けない語です

いつ出るか。 行頭の語が語彙にないとき。語彙には同義の綴りがなく、英語の一種類だけです。

直し方。 description / import / enum / group / inputs / elements / outputs / derive / define / constraint / table / fold / count / sum / max / min / sequence / result / examples / policy / overrides / clause / source / apply / shape / machine / scenario / prerequisites / chances / open のどれかに直してください。業務の語を書けるのは、名前とセルの中だけです。

最小の再現:

rule t(t) v1

foo bar

関係するコード: E004, E009

E006

error — 宣言に = がありません

いつ出るか。 enum group derive define result の行に、名前と中身を分ける = が無いとき。

直し方。 = を入れてください。例: enum k(k) = a(a) | b(b)。

最小の再現:

rule t(t) v1

enum k(k) a(a) | b(b)

関係するコード: E005

E007

error — そういう方式はありません

いつ出るか。 policy の後ろが unique と first 以外のとき。DMN の Any / Priority / Collect は採っていません。

直し方。 policy unique（重なりはすべてエラー）か policy first（先に書いた行が勝つ）に直してください。

最小の再現:

rule t(t) v1

inputs
  x(x) : bool

outputs
  r(r) : bool

table j(j)
policy any
| x | -> r(r) : bool |
| - | true           |

関係するコード: W110, E105, W105

E008

error — 空のセルがあります

いつ出るか。 表のセルが空白だけのとき。空欄は書き忘れと区別がつかないので構文エラーにしています。

直し方。 どの値でもよいなら - と書いてください。値を書き忘れていたなら、その値を書いてください。

最小の再現:

rule t(t) v1

inputs
  x(x) : bool

outputs
  r(r) : bool

table j(j)
policy unique
| x | -> r(r) : bool |
|   | true           |

関係するコード: E101

E009

error — 宣言の名前が予約語と衝突しています

いつ出るか。 宣言した名前（や別名）が語彙の語と同じとき。行指向のパーサーがその行をセクションの始まりと読んで、宣言を黙って捨てる事故を防ぐための検査です。列挙の値は行の頭に来ないので、列挙の値で出るのは、値の位置で別の意味に読まれる 11 語（not none true false starts_with default after empty exhausted by with）のときだけです。

直し方。 名前を変えてください（enum range(kind) なら enum 範囲区分(range_kind)）。予約語は src/kw.rs の表ひとつで決まっています。

最小の再現:

rule t(t) v1

enum range(kind) = a(a) | b(b)

関係するコード: E005, E011

E010

error — .. を使った範囲記法は書けません

いつ出るか。 セルに 0g..1000g のような .. があるとき。「1000g まで」が両端を含むのか含まないのかが、書いてある字から読めないためです。

直し方。 比較演算子で書き直してください。0g..1000g は <=1000g か <1000g のどちらかです。両端を決めたいなら >=0g <=1000g と並べて書いてください。

最小の再現:

rule t(t) v1

inputs
  w(w) : mass[g]  range >=0g <=10kg

outputs
  r(r) : bool

table j(j)
policy unique
| w         | -> r(r) : bool |
| 0g..1000g | true           |
| >1000g    | false          |

関係するコード: E105, E101

E011

error — 公開される名前に ASCII の別名がありません

いつ出るか。 規則名・入力・出力・並び・要素のフィールドに、ASCII でない名前が付いていて括弧の中の別名も無いとき。別名は生成コードの公開名になります（漢字は大文字を持てず、Go の公開識別子になれません。.proto のフィールドの名前は ASCII だけです）。並びは呼ぶ側が渡す入力で、要素のフィールドは呼ぶ側が埋めるので、入力と同じく公開されます。名前がもとから ASCII なら、それ自身が公開名になるので別名は要りません。

直し方。 括弧で別名を足してください（重量 : bool なら 重量(weight) : bool）。導出・定義・グループ・表の別名は任意で、書けば生成コードがその名前を使い、書かなければ宣言した名前をそのまま使います。

最小の再現:

rule t(t) v1

inputs
  重量 : bool

outputs
  r(r) : bool

table j(j)
policy unique
| 重量 | -> r(r) : bool |
| -    | true           |

別名の無い並び:

rule 明細の合計(lines_total) v1

elements 明細
  金額(amount) : money[USD]  range >=0USD <=100USD

outputs
  合計(total) : money[USD]  round down(1USD)

sum 支払い(spent) over 明細 of 金額  range >=0USD <=1000USD

define 合計 : money[USD] = 支払い

関係するコード: E009, E012

E012

error — 宣言されていない名前です

いつ出るか。 表の列や式が、どこにも宣言されていない名前を指しているとき。前に宣言していない名前は使えないので、名前はそれを使う行より上で宣言する必要があります。セルやグループに書いた値がどの列挙の値でもないときにも出ます。組み込みの区分（std/us/states など）を取り込んでいれば、注に、似た綴りの値か、その語を値に持つ別の国の名前空間が出ます。取り込んだ二つの国が同じ綴りの値を持つとき（WA はワシントン州と西オーストラリア州の符号です）は、その綴りをそのまま書いても出ます。none はこれに当たりません。optional の列では値の無いことで、optional でない列では E103 です。

直し方。 綴りを宣言に合わせるか、その入力・導出・定義を上に宣言してください。二つの国が共有する綴りなら、値の名前（Washington か Western_Australia）で書いてください。

最小の再現:

rule t(t) v1

inputs
  x(x) : bool

outputs
  r(r) : bool

table j(j)
policy unique
| y | -> r(r) : bool |
| - | true           |

関係するコード: E011, E013

E013

error — 取込先がありません

いつ出るか。 import の先が無いとき。取込先は三つあります。組み込みの名前空間（十三か国の一段目の区分。std/us/states、std/gb/nations、std/cn/provinces、std/tw/divisions、std/kr/provinces、std/in/states、std/fr/regions、std/es/communities、std/it/regions、std/de/states、std/au/states、std/br/states、std/jp/prefectures。日本の都道府県は std/都道府県 でも取り込めて、そのときは値を日本語で書きます）、.proto の列挙（import proto "<ファイル>" <列挙> -> <この規則の列挙>）、JSON Schema の列挙（import jsonschema "<ファイル>" "<ポインタ>" -> <この規則の列挙>、OpenAPI も同じ）です。あとの二つは、ファイルを読めないとき、その列挙がファイルに無いとき、行の形が違うときに出ます。rulec は YAML を読まないので、JSON にしたものを指してください。一つの国の区分を二つの名前で取り込んだとき（std/都道府県 と std/jp/prefectures）にも出ます。

直し方。 名前空間の綴りを直すか（似た綴りがあれば注に出ます）、その列挙を enum でこのファイルに書いてください。ファイルから取り込むなら、パスは規則ファイルのある場所からの相対パスで書いてください。JSON Schema のポインタは #/components/schemas/<名前> の形です。ポインタが届かなかったときは、注に、届いたところにある鍵が並びます。

最小の再現:

rule t(t) v1

import std/都道府

関係するコード: E012, E032

E014

error — 出力のセルに式は書けません

いつ出るか。 表の -> から右のセルに語が二つ以上あるとき。書けるのは値一つか名前一つだけです。残りを読み飛ばして最初の語だけを採ると、かけ算が黙って消えた生成コードができてしまいます。

直し方。 計算に名前を付けて define の行へ出し、表にはその名前だけを書いてください（| - | 率割引 |）。表に書くのは分岐だけです。

最小の再現:

rule t(t) v1

inputs
  p(p) : money[円, incl_tax]  range >=0円 <=1万円
  r(r) : rate[step 1%]  range >=0% <=100%

outputs
  o(o) : money[円, incl_tax]  round down(1円)

table j(j)
policy first
| r    | -> o(o) : money[円, incl_tax] |
| <=5% | 0円                           |
| -    | p × r                         |

関係するコード: E008, E012

E015

error — result が書けるのは最初の出力だけです

いつ出るか。 result が二つ目以降の出力を指したとき。result は最初の出力を組み立てるための書き方で、評価器も生成コードもそこにしか当てません。書いた名前が効かないまま通っていたので、number が money の枠に入っても E103 が出ませんでした。

直し方。 その出力と同じ名前の define を書いてください（define 付与点(pts) : number = 基本点 × 倍率）。出力の値は宣言の順に、同じ名前の define から取られます。result で組み立てたいなら、その出力を outputs の先頭へ移してください。

最小の再現:

rule t(t) v1

inputs
  p(p) : money[円, incl_tax]  range >=0円 <=1万円

outputs
  a(a) : money[円, incl_tax]  round down(1円)
  b(b) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| p | -> a(a) : money[円, incl_tax] |
| - | 100円                         |

result b = p

関係するコード: E016, E103

E016

error — result は一つしか書けません

いつ出るか。 一つのファイルに result の行が二本以上あるとき。組み立てられるのは最初の出力だけなので、二本目は一本目を置き換えるだけになります。以前はそれが黙って起きていました。

直し方。 一本だけ残してください。ほかの出力の値は、その出力と同じ名前の define から取られます。

最小の再現:

rule t(t) v1

inputs
  p(p) : money[円, incl_tax]  range >=0円 <=1万円

outputs
  a(a) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| p | -> a(a) : money[円, incl_tax] |
| - | 100円                         |

result a = p
result a = p + 100円

関係するコード: E015

E017

error — constraint の形が違います

いつ出るか。 constraint の行が「入力 比較 入力」になっていないとき。比較が無い、片側が名前一つでも名前を + で足した和でもない、両側とも和になっている、のどれかです。

直し方。 constraint <入力> <= <入力> の形にしてください。比較は <= < >= > の四つです。片側だけは入力を足した和にできます（constraint 値引き + ポイント <= 小計）。係数と定数は書けません。A = B を言いたいなら、A <= B と A >= B の二行に分けてください。

最小の再現:

rule t(t) v1

inputs
  a(a) : number  range >=0 <=10
  b(b) : number  range >=0 <=10

constraint a

outputs
  r(r) : bool

table j(j)
policy unique
| a | -> r(r) : bool |
| - | true           |

関係するコード: E018

E018

error — constraint は入力どうしの関係です

いつ出るか。 constraint の片側が入力でないか、順序の無い型のとき。制約は「呼び出し側が渡す値の組み合わせのうち、どれが起きるか」を言うものなので、両側とも inputs の名前で、型は金額・数量・率・number・日付のどれかでなければなりません。和の側の名前も、一つずつ同じです。

直し方。 両側を inputs の名前にしてください。導出や定義は入力から計算されるので、関係は元の入力どうしで書いてください。列挙や真偽に大小はありません。

最小の再現:

rule t(t) v1

inputs
  a(a) : number  range >=0 <=10

constraint a <= r

outputs
  r(r) : bool

table j(j)
policy unique
| a | -> r(r) : bool |
| - | true           |

関係するコード: E017, W111

E019

error — 例が、生成コードが入口で受け付けない入力です

いつ出るか。 例の入力が constraint を満たしていないとき、または入力（並びの要素のフィールドを含む）の値が宣言した範囲の外にあるとき。制約は「この組み合わせは起きない」という宣言で、範囲は「この外の値は来ない」という宣言です。完全性の検査はそれを信じて、そこには行を要求していません。生成コードもその入力を入口で受け付けません。そのため、規則はその入力の答えを決めていません。範囲の外の例と、二つの日付のあいだの constraint を破る例は、いままで検査を通り、その例から作ったベクタは、生成コードでエラーになっていました。

直し方。 例の値を直してください。その値や組み合わせが本当に来るなら、範囲を広げるか、制約を消してください。

最小の再現:

rule t(t) v1

inputs
  a(a) : number  range >=0 <=10
  b(b) : number  range >=0 <=10

constraint a <= b

outputs
  r(r) : bool

table j(j)
policy unique
| a | b | -> r(r) : bool |
| - | - | true           |

examples
| a | b | -> r |
| 5 | 1 | true |

関係するコード: E017, E018, E101

E020

error — elements の宣言が正しくありません

いつ出るか。 elements に名前が無いとき、または宣言した並びをどの行もたどらないとき。並びは、count・sum・max・min・fold のどれかが over で指して、はじめて規則の値になります。たどらない並びのフィールドを読む項目は、どの要素の値を読むのかが決まりません。規則は並びをいくつでもたどれます（elements は何本でも書けます）。

直し方。 elements 運賃行(fee_rows) の形で名前を書き、続く行に一要素ぶんのフィールドを inputs と同じように書いてください。並びが要るなら、たどる行を足してください。要らないなら、その elements を消してください。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=0 <=10

elements xs(xs)
  k(k) : number  range >=0 <=10

outputs
  r(r) : bool

table j(j)
policy unique
| n | -> r(r) : bool |
| - | true           |

関係するコード: E028, E021, E031

E021

error — fold の書き方が正しくありません

いつ出るか。 fold <判定の列> over <並びの名前> [-> <名前> [: <型>]] になっていないか、判定の行き先が next stop stop with <値> take_unique <値> take_first <値> keep_max <値> by <鍵> take_weighted <値> by <重み> のどれでもないか、畳もうとしている列が列挙でないとき。答えの名前が、入力、要素のフィールド、たどる並び、上で宣言した値と同じとき、出力でない名前に型が無いとき、出力の名前に出力と違う型を書いたとき、畳み込みとほかの項目が同じ名前を決めるときも、これです。畳み込みの値が、その値を決める時点に無い値を読むときもこれです。empty と exhausted の値は要素を見ていないところで決まるので、要素の値を読めません。どの値も、この畳み込みの答えから計算する値を読めません（要素の判定がその答えを読むと、答えを出す前に答えが要ります）。held は最後まで見終えたときの値なので、exhausted の値にだけ書けます。

直し方。 見出しと行き先を上の形に直してください。take とだけ書くことはできません。一件だけ採るのか、最初の一件を採るのかは、書く人が選ぶことだからです。要素の値を答えにするなら、take_unique・take_first・keep_max で採ってから、exhausted -> held で返してください。後ろの項目が答えを読むなら -> <名前> で名前を付けます。自分の答えを読む判定は、別の畳み込みにすれば二回目の歩きで読めます。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=0 <=10

elements xs(xs)
  k(k) : number  range >=0 <=10

outputs
  r(r) : bool

table j(j)
policy unique
| n | -> r(r) : bool |
| - | true           |

fold r
  empty -> false

関係するコード: E020, E022, E023, E024

E022

error — 要素がゼロ件のときの答えが宣言されていません

いつ出るか。 fold に empty -> <値> が無いとき、max・min に empty <値> が無いとき。空の並びは必ず来ます。手で書いたループがいちばんよく見落とすのがこの場合で、たいていは最初の要素をそのまま読もうとして、実行時に落ちます。max・min では、where に当てはまる要素が一つも無いときも、この値が答えです。

直し方。 empty -> <値>（max・min では empty <値>）を足してください。何を返すかは業務の判断で、rulec が決められることではありません。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  b -> take_first k
  exhausted -> held

max に empty が無い:

rule t(t) v1

elements xs(xs)
  k(k) : number  range >=0 <=10

outputs
  r(r) : number  round down(1)

max r over xs of k

関係するコード: E023, E024

E023

error — 最後まで見終えたときの答えが宣言されていません

いつ出るか。 fold に exhausted -> <値> が無いとき。どの要素も打ち切らずに並びが尽きた場合の答えです。保持していた暫定の値をそのまま返すつもりでも、書くまでは決まっていません。

直し方。 exhausted -> <値> を足してください。保持しているものを返すなら exhausted -> held です。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  b -> take_first k
  empty -> 0円

関係するコード: E022, E024

E024

error — 行き先の無い判定があります

いつ出るか。 表が出しうる判定のどれかに、fold の行き先が無いとき。その判定の要素が来たら、次にどうするかが決まっていません。表の完全性と同じ検査を、畳み込みの側に当てたものです。

直し方。 行き先を足すか、表がその値を出さないようにしてください。逆に、どの要素もたどり着けない判定に行き先があるときは、W115 が出ます。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  empty -> 0円
  exhausted -> held

関係するコード: E022, E023, W115

E025

error — 例に並びの列がありません

いつ出るか。 並びをたどる規則に examples があるのに、elements の名前の列が見出しに無いとき。どの並びをたどるかが決まっていない例は、答えの決まっていない例です。

直し方。 sequence <名前> で並びを書き、例の見出しに並びの列を足して、その名前をセルに書いてください。行がゼロ本の sequence は、要素ゼロ件の例になります。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  b -> take_first k
  empty -> 0円
  exhausted -> held

examples
| -> r |
| 0円  |

関係するコード: E026, E027

E026

error — sequence の書き方が正しくありません

いつ出るか。 sequence のフィールドが elements のフィールドとそろっていないとき。余分なフィールドがある、フィールドが足りない、見出しに同じフィールドの列が二つある、-> がある、たどる並びそのものが無い、同じ名前が二つある、セルが値でない（範囲や - が書いてある）、のどれかです。

直し方。 elements のフィールドをそのまま見出しにして、一行に一件ぶんの値を書いてください。これは表ではなく、実際に渡す値の並びです。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  b -> take_first k
  empty -> 0円
  exhausted -> held

sequence s(s)
| m   |
| 3円 |

関係するコード: E025, E020

E027

error — 例が指す並びがありません

いつ出るか。 例の並びの列に書かれた名前の sequence が無いとき、またはその列に名前でないもの（数や範囲）が書かれているとき。

直し方。 その名前で sequence を書くか、セルを、書いてある sequence の名前に直してください。

最小の再現:

rule t(t) v1

enum v(v) = a(a) | b(b)

elements xs(xs)
  k(k) : money[円, incl_tax]  range >=0円 <=10円

outputs
  r(r) : money[円, incl_tax]  round down(1円)

table j(j)
policy unique
| k     | -> d(d) : v |
| <=5円 | a           |
| >5円  | b           |

fold d over xs
  a -> next
  b -> take_first k
  empty -> 0円
  exhausted -> held

examples
| xs   | -> r |
| nope | 0円  |

関係するコード: E025, E026

E028

error — count の書き方が正しくありません

いつ出るか。 count <名前>(<別名>) over <並びの名前> where <列> = <値> になっていないとき。over が無い、where が無い、指した並びが elements で宣言されていない、= の右に値が無い。sum <名前>(<別名>) over <並びの名前> of <列>、max・min の <名前>(<別名>) over <並びの名前> of <列> [where <列> [= <値>]] empty <値> の形でないときも、これです。

直し方。 上の形に直してください。= <値> は、真偽の列を数えるときだけ省けます。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=0 <=10

elements xs(xs)
  b(b) : bool

outputs
  r(r) : bool

count h(h) where b  range >=0 <=10

table j(j)
policy unique
| n | -> r(r) : bool |
| - | true           |

関係するコード: E029, E030, E020

E029

error — この列は数えられません

いつ出るか。 where が指す列が、要素ごとに決まる値でないとき（入力や導出は一件の呼び出しに一つしかないので、数えても 0 か 1 です）。値が有限の集合でないとき。書いた値がその列挙にないとき。列挙の列なのに = <値> が無いとき。sum・max・min の of が指す列も同じで、over が指すのと別の並びの値のとき、sum の列が数でないとき、max・min の列が数・日付・順序つきの列挙のどれでもないときにも出ます（max・min では題が「この列はまとめられません」になります）。

直し方。 要素のフィールドか、要素ごとの表が出した列を指してください。判定を表に書けば、その分類そのものも完全性の検査に掛かります。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=0 <=10
  ok(ok) : bool

elements xs(xs)
  b(b) : bool

outputs
  r(r) : bool

count h(h) over xs where ok  range >=0 <=10

table j(j)
policy unique
| h | -> r(r) : bool |
| - | true           |

関係するコード: E028, E012

E030

error — count に範囲が要ります

いつ出るか。 count の行に range >=0 <=<上限> が無いか、上限が無いか、下限が負のとき。範囲には二つの意味があります。数えた結果を列に使ったときに完全性の検査が調べる値の全体と、並びの長さの上限です。

直し方。 range >=0 <=100 の形で書いてください。生成コードは、この上限より長い並びを入口で受け付けません。数値の入力と同じで、宣言の外は黙って通しません。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=0 <=10

elements xs(xs)
  b(b) : bool

outputs
  r(r) : bool

count h(h) over xs where b

table j(j)
policy unique
| h | -> r(r) : bool |
| - | true           |

関係するコード: E028, E112

E031

error — 一つの項目が、二つの並びの要素を読んでいます

いつ出るか。 一つの項目（表・節・導出・定義・畳み込み）が、二つの並びの要素の値を読むとき。要素の値は、その並びをたどっているあいだにしかありません。二つの並びの要素を一緒に読むには、片方の並びの要素ごとに、もう片方を最初からたどることになります（並びの中で並びをたどる）。そうすると歩きの数が並びの長さにつれて増え、検査が終わりません。出力が要素ごとの値のときも、これです。たどり終えたあとには、一つの値に決まりません。規則の項目は、要素によらない項目と要素ごとの項目に分かれ、要素ごとの項目は、読む集計の答えが決まったあとの歩きで計算されます（集計の答えを読む要素ごとの項目は二回目の歩きに入ります）。

直し方。 片方の並びを count・sum・max・min・fold で一つの値にしてから、もう片方の項目で読んでください。その項目は、その値が決まったあとの二回目の歩きで計算されます。要素ごとの値を出力にするなら、集計で並び全体の一つの値にしてから出力にしてください。

最小の再現:

rule t(t) v1

elements xs(xs)
  a(a) : number  range >=0 <=10

elements ys(ys)
  b(b) : number  range >=0 <=10

outputs
  r(r) : number  round down(1)
  s(s) : number  round down(1)

define both(both) : number = a + b

sum r over xs of both  range >=0 <=1000

sum s over ys of b  range >=0 <=1000

要素ごとの値の出力:

rule 大きな部品(big_parts) v1

elements 部品(parts)
  単価(price) : number  range >=0 <=100

outputs
  合計(total) : number  round down(1)
  大きい(big) : bool

table 大きさ(big_of)
policy unique
| 単価 | -> 大きい : bool |
| >=50 | true             |
| <50  | false            |

sum 合計 over 部品 of 単価  range >=0 <=10000

関係するコード: E021, E029, E020

E032

error — 取り込んだ列挙と宣言がずれています

いつ出るか。 import proto や import jsonschema が指す列挙の値と、この規則の enum の値（別名があれば別名）がそろっていないとき。片方にしか無い値は、どちらの側のものも名前で出ます。値が増えるのはたいてい proto の側で、それは規則の外での変更が、互換な変更として通ってしまったものです。

直し方。 増えた値をこの規則の enum に足してください。値の名前に別名を付けて書く列挙なら、名前は自分で決めてください。消えた値なら、この規則からも消してください。値を足すと、次はその値に行が要るかを E033 が問います。

最小の再現:

rule t(t) v1

import proto "tier.proto" Tier -> v
enum v(v) = one(one)

inputs
  x(x) : v

outputs
  r(r) : bool

table j(j)
policy unique
| x   | -> r(r) : bool |
| one | true           |

隣に置く tier.proto:

syntax = "proto3";

enum Tier {
  TIER_UNSPECIFIED = 0;
  TIER_ONE = 1;
  TIER_TWO = 2;
}

関係するコード: E013, E033, E101

E033

error — 外から来た列挙の値に、行も default もありません

いつ出るか。 取り込んだ列挙の値が、どの行にも現れず、default も付いていないとき。寄与が extend で足した値が、表のどの行にも名前で書かれず、- の行、その値を外さない not: の行、その値まで覆うようになった比べるセルの行に黙って落ちるときも同じです（行ごとに言います）。自分で書いた値なら書き忘れの警告（W111）で済みますが、契約や寄与から来た値の場合は外の変更がまだ誰にも読まれていないことを示すので、rulec はエラーにして止めます。既定の行がある表では完全性の検査が通ってしまい、新しい値には既定の行の答えが黙って当たります。

直し方。 その値の行を表に足すか、値の宣言に default を付けてください。寄与が足した値なら、開いた表に寄与が行を足すか、extend の行に default を付けてください。default は「既定の行に落ちるのが意図です」という宣言で、誰かがその値の扱いを決めたことを示します。

最小の再現:

rule t(t) v1

import proto "tier.proto" Tier -> v
enum v(v) = one(one) | two(two)

inputs
  x(x) : v

outputs
  r(r) : bool

table j(j)
policy first
| x   | -> r(r) : bool |
| one | true           |
| -   | false          |

隣に置く tier.proto:

syntax = "proto3";

enum Tier {
  TIER_UNSPECIFIED = 0;
  TIER_ONE = 1;
  TIER_TWO = 2;
}

寄与が足した値（extend）:

contribution c(c) v1
to "base.rule" signature:69e01897ab91b191

extend kind with z

隣に置く base.rule:

rule base(base) v1

enum kind(kind) = a(a) | b(b)  open

inputs
  k(k) : kind

outputs
  fee(fee) : number  round down(1)

table t(t)
policy first
| k | -> fee : number |
| a | 1               |
| - | 2               |

関係するコード: E032, W111, E101, E067

E034

error — 同じ名前が二度あります

いつ出るか。 一つのファイルが同じ種類の名前を二度書いたとき、二つ目のところで出ます。種類は、値（入力、たどる並びとその要素のフィールド、出力、derive・define・count・sum・max・min・open と、表や節が決める出力の列）、表と節、列挙、一つの列挙の値、グループと一つのグループに書いた値、shape、出典、準用、前提のつながり、一つの表の行ラベル、表と例の見出しの列です。出力はそれを決めるものと同じ名前で、一つの名前をいくつかの表や節で決めることもできます。値のそれ以外の重なりは、入力と同じ名前の出力も含めて、一つの名前に二つの値があることになるので止まります。列挙の値と同じ名前のグループも、一つの語に二つの読み方があるので止まります。一つの並びの二つの名前が生成するコードで同じ識別子になるとき（一方の別名が、他方の別名か名前と同じ）、一つの名前に二つの別名を書いたとき、enums のファイルで列挙の名前がほかの列挙の別名と同じとき（import enum は名前でも別名でも列挙を探します）にも出ます。二つの名前の識別子が違っても、それを書くどの言語でも同じに綴るときにも出ます。二つの列挙の型と一つの列挙の二つの値（どちらも PascalCase で書きます）、二つの前提のつながりの関数（snake_case）、並びが二つ以上ある規則の要素の型、呼ぶ側のオブジェクトから入力を読む関数の引数として並ぶ shape と入力や並びです。いくつかの言語だけが同じに綴るものは W121 です。import enum で読んだ列挙と一緒に来たグループはこの規則の名前やほかの import enum が読んだものと、寄与が足す入力は足す先の規則の名前と比べます。畳み込みの答えの名前は E021、準用の出力に付けた名前は E041 で止まります。

直し方。 どちらかを消すか、名前を変えてください（行ラベルと見出しの列も同じです）。同じ識別子になる二つの名前は、どちらかに別の別名を付けてください。import enum で読んだ列挙なら、-> <別の名前> で読めます。

最小の再現:

rule 重さの判定(weight_check) v1

inputs
  重さ(weight) : number  range >=0 <=9
  重さ(weight) : number  range >=0 <=99

outputs
  重い(heavy) : bool

table 判定(decide)
policy unique
| 重さ | -> 重い |
| <=5  | false   |
| >5   | true    |

一つの列挙に同じ値が二つ:

rule 送料無料(free_shipping) v1

enum 会員区分(member_kind) = 一般(basic) | ゴールド(gold) | 一般(basic)

inputs
  会員(member) : 会員区分

outputs
  無料(free) : bool

table 判定(decide)
policy unique
| 会員     | -> 無料 |
| 一般     | false   |
| ゴールド | true    |

同じ識別子になる二つの名前:

rule 大きさの判定(size_check) v1

inputs
  重さ(weight) : number  range >=0 <=9
  長さ(weight) : number  range >=0 <=9

outputs
  大きい(large) : bool

table 判定(decide)
policy first
| 重さ | 長さ | -> 大きい |
| >5   | -    | true      |
| -    | >5   | true      |
| -    | -    | false     |

表の見出しに同じ列が二つ:

rule 重さの判定(weight_check) v1

inputs
  重さ(weight) : number  range >=0 <=9

outputs
  重い(heavy) : bool

table 判定(decide)
policy first
| 重さ | 重さ | -> 重い |
| <=5  | >5   | true    |
| -    | -    | false   |

型の名前が一つになる二つの列挙:

rule 段階ごとの料金(tier_fee) v1

enum 会員の段階(tier_level) = 一般(basic) | ゴールド(gold)
enum 地域の段階(tierLevel) = 近い(low) | 遠い(high)

inputs
  会員(member) : 会員の段階
  地域(band)   : 地域の段階

outputs
  料金(fee) : money[USD]  round down(1USD)

table 会員ごとの料金(fee_by_member)
policy unique
| 会員     | 地域 | -> 料金 |
| 一般     | -    | 1USD    |
| ゴールド | 近い | 2USD    |
| ゴールド | 遠い | 3USD    |

一つの表の二つの行に同じラベル:

rule t(t) v1

inputs
  a(a) : bool

outputs
  x(x) : bool

table 表(t1)
   | a     | -> x  |
r1 | true  | true  |
r1 | false | false |

関係するコード: E009, E035, E021, E041, E075, W121

E035

error — overrides の指す先がありません

いつ出るか。 overrides が指す表が無いか、この表より後ろで宣言されているか、表:行ラベル の行にそのラベルが無いとき。行の書き方が読めないときも同じです。例外は本文の後に書くので、指す先はいつも上にあります。

直し方。 上で宣言した表か、その行（行の先頭にラベルを書き、表:ラベル で指す）を指定してください。優先する側を後に書いてください。

最小の再現:

rule t(t) v1

inputs
  a(a) : bool

outputs
  x(x) : bool

table 表(t1)
overrides 無い表
| a     | -> x  |
| true  | true  |
| false | false |

関係するコード: E034, E036

E036

error — overrides の相手が同じ出力を定めていません

いつ出るか。 overrides の指す表が、この表とは別の出力を定めているとき。優先の順序は、同じ出力を定める定義のあいだにだけあります。

直し方。 同じ出力を定める表を指すか、この表の出力列をその相手と揃えてください。

最小の再現:

rule t(t) v1

inputs
  a(a) : bool

outputs
  x(x) : bool
  y(y) : bool

table 甲(ko)
| a | -> x |
| - | true |

table 乙(otsu)
overrides 甲
| a | -> y |
| - | true |

関係するコード: E035, E045

E037

error — 引用した箇所のハッシュが固定されていません

いつ出るか。 @出典 第91条 のように引用した箇所に、source の行の下の 第91条 sha256:… というハッシュの行が無いとき。file の出典なら、その行に sha256:… が無いとき。法令を箇所無しで @法 とだけ引用したとき、箇所の書き方や、引用・宣言の形が読めないときも同じです（隣に置いたファイルは @郵便 と丸ごと引用できます）。文書から引けるのは表なので、引用箇所は 表3（文書の中で三つめの表）か table3 と書いてください。それ以外の書き方は読めません。語として読めない箇所は " で囲んでください（@osha "§1910.157"）。ハッシュが無いと、取り直したコピーの中身が変わっていても、check は何も言えません。

直し方。 原文を読んで、転記した行が正しいことを確かめたら、fix.text の行を貼るか rulec source pin <file.rule> を実行して、いまのコピーのハッシュを書き込んでください。

最小の再現:

rule t(t) v1

source 法 = law "000AC0000000001" asof 2026-04-01

inputs
  a(a) : bool

outputs
  x(x) : bool

table 表(t1)  @法 第1条
| a | -> x |
| - | true |

隣に置く sources/law/000AC0000000001@2026-04-01/MainProvision-Article_1.xml:

<Article Num="1"><ArticleTitle>第一条</ArticleTitle><Paragraph Num="1"><ParagraphNum/><ParagraphSentence><Sentence>甲は、乙とする。</Sentence></ParagraphSentence></Paragraph></Article>

関係するコード: E038, E039, W119

E038

error — 引用した箇所が変わっています

いつ出るか。 規則に書いてあるハッシュと、規則の隣にあるコピーのハッシュが違うとき。コピーを取り直した PR で出ます。注に、その箇所を引用している表・節・行が出るので、読み直すのはそこだけで済みます。

直し方。 コピーの差分を読み、転記した行がまだ正しければ fix.text のとおりハッシュの行を書き換えてください（rulec source pin でも書けます）。行が変わるなら、先に行を直してください。

最小の再現:

rule t(t) v1

source 法 = law "000AC0000000001" asof 2026-04-01
  第1条 sha256:0000000000000000

inputs
  a(a) : bool

outputs
  x(x) : bool

table 表(t1)  @法 第1条
| a | -> x |
| - | true |

隣に置く sources/law/000AC0000000001@2026-04-01/MainProvision-Article_1.xml:

<Article Num="1"><ArticleTitle>第一条</ArticleTitle><Paragraph Num="1"><ParagraphNum/><ParagraphSentence><Sentence>甲は、乙とする。</Sentence></ParagraphSentence></Paragraph></Article>

関係するコード: E037, E039

E039

error — 出典のコピーがありません

いつ出るか。 引用した箇所のコピーが規則の隣に無いとき（法令なら sources/law/<法令ID>@<日付>/<要素>.xml、文書の表なら文書の隣の 料金表.md.fragments/表3.tsv）、または file の出典そのものが読めないとき。check は通信をせず、文書の中身も見ないので、コピーが無ければ照合できません。

直し方。 rulec source fetch <file.rule> を実行してください。政府の法令データベース（e-Gov 法令検索）から引用箇所を取り、文書からは引いた表を取り出して、規則の隣に保存します。コピーは git に入れてください。

最小の再現:

rule t(t) v1

source 法 = law "000AC0000000001" asof 2026-04-01

inputs
  a(a) : bool

outputs
  x(x) : bool

table 表(t1)  @法 第2条
| a | -> x |
| - | true |

関係するコード: E037, E038

E040

error — 固定した元のファイルが、書いてあるハッシュと違います

いつ出るか。 apply の見出しに固定が無いとき、または書いてある固定と、いま隣にある元の規則が違うとき。固定は meaning:…（元の規則の行と宣言から、コメント、description、出典の引用を除いたもの）で、前に書いた sha256:…（ファイルのバイト列）もそのまま読みます。元の規則の行が改正されれば、それを準用するこの規則の答えも変わっています。寄与のファイルの to と after の signature:… が無いとき、合わないときも同じです。こちらは足す先の形（名前、入力と出力、開いた値と開いた出力、開いた列挙と塊、寄与が読む名前の宣言）で、元の行やコメントを直しても落ちず、形が変わると、何が変わったかを言います（リポジトリの履歴に固定したときの版があれば）。固定を書いておかないと、その変化を誰も承認しないまま通ってしまいます。

直し方。 rulec diff <古い版> <新しい版> でこの規則の答えが何件いくら動くかを見て、それでよければ、見出しを fix.text のとおり書き換えるか rulec source pin <file.rule> を実行して固定を書き直してください。寄与なら、寄与を新しい形で読み直してから、rulec source pin <寄与のファイル> で signature: を書き直してください。

最小の再現:

rule t(t) v1

inputs
  n(n) : number  range >=1 <=10

outputs
  y(y) : number  round down(1)

apply 呼(c) = "呼び先.rule"
  a = n
  x -> y

隣に置く 呼び先.rule:

rule 呼び先(callee) v1

inputs
  a(a) : number  range >=1 <=10

outputs
  x(x) : number  round down(1)

table 表(t)
policy unique
   | a   | -> x |
小 | <=5 | 1    |
大 | >5  | 2    |

寄与の signature: が足す先の形と違う:

contribution c(c) v1
to "base.rule" signature:0123456789abcdef

extend kind with z

隣に置く base.rule:

rule base(base) v1

enum kind(kind) = a(a) | b(b)  open

inputs
  k(k) : kind

outputs
  fee(fee) : number  round down(1)

table t(t)
policy first
| k | -> fee : number |
| a | 1               |
| - | 2               |